--------------------------------------------------------------------------------
-- CERN (BE-CO-HT)
-- Top level entity of CONV-TTL-BLO
-- http://www.ohwr.org/projects/conv-ttl-blo
--------------------------------------------------------------------------------
--
-- unit name: conv_ttl_blo.vhd
--
-- author: Theodor-Adrian Stana (t.stana@cern.ch)
--
-- version: 1.0
--
-- description: Top entity of CONV-TTL-BLO
--
-- dependencies:
--
-- references:
--   [1] ELMA, Access to board data using SNMP and I2C
--       http://www.ohwr.org/documents/227
--
--------------------------------------------------------------------------------
-- GNU LESSER GENERAL PUBLIC LICENSE
--------------------------------------------------------------------------------
-- This source file is free software; you can redistribute it and/or modify it
-- under the terms of the GNU Lesser General Public License as published by the
-- Free Software Foundation; either version 2.1 of the License, or (at your
-- option) any later version. This source is distributed in the hope that it
-- will be useful, but WITHOUT ANY WARRANTY; without even the implied warranty
-- of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
-- See the GNU Lesser General Public License for more details. You should have
-- received a copy of the GNU Lesser General Public License along with this
-- source; if not, download it from http://www.gnu.org/licenses/lgpl-2.1.html
--------------------------------------------------------------------------------
library ieee;
library unisim;

use ieee.std_logic_1164.all;
use ieee.numeric_std.all;
use unisim.vcomponents.all;

use work.bicolor_led_ctrl_pkg.all;
use work.wishbone_pkg.all;
use work.gencores_pkg.all;

entity conv_ttl_blo is
  generic
  (
    g_nr_ttl_chan : natural := 6;
    g_nr_inv_chan : natural := 4
  );
  port 
  (
--    clk20_vcxo_i           : in  std_logic;
    fpga_clk_p_i           : in  std_logic; --Using the 125MHz clock
    fpga_clk_n_i           : in  std_logic;
    
    -- LEDs
    led_ctrl0_o            : out std_logic;
    led_ctrl0_oen_o        : out std_logic;
    led_ctrl1_o            : out std_logic;
    led_ctrl1_oen_o        : out std_logic;
    led_multicast_2_0_o    : out std_logic;
    led_multicast_3_1_o    : out std_logic;
    led_wr_gmt_ttl_ttln_o  : out std_logic;
    led_wr_link_syserror_o : out std_logic;
    led_wr_ok_syspw_o      : out std_logic;
    led_wr_ownaddr_i2c_o   : out std_logic;
    
    -- I/Os for pulses
    pulse_front_led_n_o    : out std_logic_vector(g_nr_ttl_chan downto 1);
    pulse_rear_led_n_o     : out std_logic_vector(g_nr_ttl_chan downto 1);
    fpga_input_ttl_n_i     : in  std_logic_vector(g_nr_ttl_chan downto 1);
    fpga_out_ttl_o         : out std_logic_vector(g_nr_ttl_chan downto 1);
    fpga_blo_in_i          : in  std_logic_vector(g_nr_ttl_chan downto 1);
    fpga_trig_blo_o        : out std_logic_vector(g_nr_ttl_chan downto 1);
    inv_in_n_i             : in  std_logic_vector(g_nr_inv_chan downto 1);
    inv_out_o              : out std_logic_vector(g_nr_inv_chan downto 1);
    
    -- Output enable lines
    fpga_oe_o              : out std_logic;
    fpga_blo_oe_o          : out std_logic;
    fpga_trig_ttl_oe_o     : out std_logic;
    fpga_inv_oe_o          : out std_logic;
    
    --TTL/INV_TTL_N
    ttl_switch_n_i         : in  std_logic;
    
    extra_switch_n_i       : in  std_logic_vector(7 downto 1);
    
    -- Lines for the i2c_slave
    scl_i                  : in  std_logic;
    scl_o                  : out std_logic;
    scl_oe_o               : out std_logic;
    sda_i                  : in  std_logic;
    sda_o                  : out std_logic;
    sda_oe_o               : out std_logic;
    fpga_ga_i              : in  std_logic_vector(4 downto 0);
    fpga_gap_i             : in  std_logic;

    -- Flash memory lines
    fpga_prom_cclk_o       : out std_logic;
    fpga_prom_cso_b_n_o    : out std_logic;
    fpga_prom_mosi_o       : out std_logic;
    fpga_prom_miso_i       : in  std_logic;

    -- It allows power sequencing of the 24V rail after a security delay
    mr_n_o                 : out std_logic;

    -- RTM identifiers, should match with the expected values
    fpga_rtmm_n_i        : in std_logic_vector(2 downto 0);
    fpga_rtmp_n_i        : in std_logic_vector(2 downto 0)
  );
end conv_ttl_blo;


architecture behav of conv_ttl_blo is

  --============================================================================
  -- Type declarations
  --============================================================================
  type t_ttlbar_nosig_cnt is array (1 to g_nr_ttl_chan) of unsigned(13 downto 0);
  type t_pulse_led_cnt is array (1 to g_nr_ttl_chan) of unsigned(22 downto 0);

  --============================================================================
  -- Constant declarations
  --============================================================================
  -- Firmware version
  constant c_fwvers          : std_logic_vector(15 downto 0) := x"0200";

  -- Number of Wishbone masters and slaves, for wb_crossbar
  constant c_nr_masters      : natural :=  1;
  constant c_nr_slaves       : natural :=  2;

  -----------------------------------------
  -- Memory map
  -- * all registers are word-addressable
  -- * all registers are word-aligned
  -----------------------------------------
  --    CONV_REGS       [000-040]
  --    MULTIBOOT       [040-080]
  -----------------------------------------
  -- slave order definitions
  constant c_slv_conv_regs : natural := 0;
  constant c_slv_multiboot : natural := 1;

  -- base address definitions
  constant c_addr_conv_regs : t_wishbone_address := x"00000000";
  constant c_addr_multiboot : t_wishbone_address := x"00000040";

  -- address mask definitions
  constant c_mask_conv_regs : t_wishbone_address := x"00000FC0";
  constant c_mask_multiboot : t_wishbone_address := x"00000FC0";

  -- addresses constant for Wishbone crossbar
  constant c_addresses : t_wishbone_address_array(c_nr_slaves-1 downto 0)
                  := (
                       c_slv_conv_regs => c_addr_conv_regs,
                       c_slv_multiboot => c_addr_multiboot
                     );

  -- masks constant for Wishbone crossbar
  constant c_masks : t_wishbone_address_array(c_nr_slaves-1 downto 0)
                  := (
                       c_slv_conv_regs => c_mask_conv_regs,
                       c_slv_multiboot => c_mask_multiboot
                     );

  --============================================================================
  -- Component declarations
  --============================================================================
  -- Reset generator component
  -- (use: global reset generation, output reset generation)
  component reset_gen is
    generic
    (
      -- Reset time in number of clk_i cycles
      g_reset_time : positive := 5_000_000
    );
    port
    (
      clk_i   : in  std_logic;
      rst_i   : in  std_logic;
      rst_n_o : out std_logic
    );
  end component reset_gen;

  -- Pulse generator component
  -- (use: output pulse generation, pulse status LEDs)
  component ctb_pulse_gen is
    generic 
    (
      -- Pulse width, in number of clk_i cycles
      g_pwidth : natural := 15;

      -- Glitch filter length:
      -- g_gf_len=1 => trigger width should be > 1 clk_i cycle
      -- g_gf_len=2 => trigger width should be > 2 clk_i cycles
      -- etc.
      g_gf_len : natural := 4
    );
    port
    (
      clk_i     : in  std_logic;
      rst_n_i   : in  std_logic;
      
      -- Glitch filter enable input
      -- '1' - Glitch filter disabled (glitch-sensitive, no output jitter)
      -- '0' - Glitch filter enabled (glitch-insensitive, with output jitter)
      gf_en_n_i : in  std_logic;

      -- Enable input, pulse generation is enabled when '1'
      en_i      : in  std_logic;

      -- Trigger input, has to be '1' to assure pulse output with delay no greater
      -- than internal gate delays.
      trig_i    : in  std_logic;
      
      -- Pulse output, active-high
      -- latency:
      --    glitch filter disabled: none
      --    glitch filter enabled: g_gf_len+3 clk_i cycles
      pulse_o   : out std_logic
    );
  end component ctb_pulse_gen;

  -- I2C bridge
  -- (use: convert I2C transfers into WB transfers on memmapped registers)  
  component vbcp_wb is
    port
    (
      -- Clock, reset
      clk_i      : in  std_logic;
      rst_n_i    : in  std_logic;

      -- I2C lines
      sda_en_o   : out std_logic;
      sda_i      : in  std_logic;
      sda_o      : out std_logic;
      scl_en_o   : out std_logic;
      scl_i      : in  std_logic;
      scl_o      : out std_logic;

      -- I2C address
      i2c_addr_i : in  std_logic_vector(6 downto 0);

      -- Transfer In Progress (TIP) and Error outputs
      -- TIP : '1' when the I2C slave detects a matching I2C address, thus a
      --           transfer is in progress
      --       '0' when idle
      -- ERR : '1' when the SysMon attempts to access an invalid WB slave
      --       '0' when idle
      tip_o  : out std_logic;
      err_o  : out std_logic;

      -- Wishbone master signals
      wbm_stb_o  : out std_logic;
      wbm_cyc_o  : out std_logic;
      wbm_sel_o  : out std_logic_vector(3 downto 0);
      wbm_we_o   : out std_logic;
      wbm_dat_i  : in  std_logic_vector(31 downto 0);
      wbm_dat_o  : out std_logic_vector(31 downto 0);
      wbm_adr_o  : out std_logic_vector(31 downto 0);
      wbm_ack_i  : in  std_logic;
      wbm_rty_i  : in  std_logic;
      wbm_err_i  : in  std_logic
    );
  end component vbcp_wb;

  -- Xilinx MultiBoot component
  -- (use: remote reprogramming of the FPGA)
  component xil_multiboot is
    port
    (
      -- Clock and reset input ports
      clk_i   : in  std_logic;
      rst_n_i : in  std_logic;
  
      -- Wishbone ports
      wbs_i   : in  t_wishbone_slave_in;
      wbs_o   : out t_wishbone_slave_out;
  
      -- SPI ports
      spi_cs_n_o : out std_logic;
      spi_sclk_o : out std_logic;
      spi_mosi_o : out std_logic;
      spi_miso_i : in  std_logic
    );
  end component xil_multiboot;

  -- RTM detector component
  -- (use: detect the presence of an RTM/P module)
  component rtm_detector is
    port 
    (
      rtmm_i    : in std_logic_vector(2 downto 0);
      rtmp_i    : in std_logic_vector(2 downto 0);
      rtmm_ok_o : out std_logic;
      rtmp_ok_o : out std_logic
    );
  end component rtm_detector;

  -- Converter board control registers
  component conv_regs is
    port (
      rst_n_i                                  : in     std_logic;
      clk_sys_i                                : in     std_logic;
      wb_adr_i                                 : in     std_logic_vector(1 downto 0);
      wb_dat_i                                 : in     std_logic_vector(31 downto 0);
      wb_dat_o                                 : out    std_logic_vector(31 downto 0);
      wb_cyc_i                                 : in     std_logic;
      wb_sel_i                                 : in     std_logic_vector(3 downto 0);
      wb_stb_i                                 : in     std_logic;
      wb_we_i                                  : in     std_logic;
      wb_ack_o                                 : out    std_logic;
      wb_stall_o                               : out    std_logic;
    -- Port for std_logic_vector field: 'bits' in reg: 'Board ID register'
      conv_regs_id_bits_o                      : out    std_logic_vector(31 downto 0);
    -- Port for std_logic_vector field: 'fwvers' in reg: 'Status register'
      conv_regs_sr_fwvers_i                    : in     std_logic_vector(15 downto 0);
    -- Port for std_logic_vector field: 'switches' in reg: 'Status register'
      conv_regs_sr_switches_i                  : in     std_logic_vector(7 downto 0);
    -- Port for std_logic_vector field: 'RTM detection' in reg: 'Status register'
      conv_regs_sr_rtm_i                       : in     std_logic_vector(5 downto 0);
    -- Port for BIT field: 'Reset unlock bit' in reg: 'Control register'
      conv_regs_cr_rst_unlock_o                : out    std_logic;
    -- Port for BIT field: 'Reset bit' in reg: 'Control register'
      conv_regs_cr_rst_o                       : out    std_logic
    );
  end component conv_regs;

  --============================================================================
  -- Signal declarations
  --============================================================================
  -- Clock signals
  signal clk125                     : std_logic;
  signal clk_50, clk_buf_50         : std_logic;
  signal clk_200, clk_buf_200       : std_logic;
  signal clk_250, clk_buf_250       : std_logic;
  signal pll_fb_in, pll_fb_out      : std_logic;
  signal pll_locked                 : std_logic;

  -- Reset signals
  signal rst_n, rst                 : std_logic;

  -- RTM detection signals
  signal rtmm, rtmp                 : std_logic_vector(2 downto 0);
  signal rtmm_ok, rtmp_ok           : std_logic;

  -- Signals to/from converter system registers component
  signal rtm_lines                  : std_logic_vector(5 downto 0);
  signal switches_n                 : std_logic_vector(7 downto 0);

  -- Signals for pulse generation triggers
  signal trig_a                     : std_logic_vector(g_nr_ttl_chan downto 1);
  signal trig_inv                   : std_logic_vector(g_nr_inv_chan downto 1);
  signal trig_ttl_a, trig_blo_a     : std_logic_vector(g_nr_ttl_chan downto 1);
  signal trig_synced_edge           : std_logic_vector(g_nr_ttl_chan downto 1);
  signal trig_synced                : std_logic_vector(g_nr_ttl_chan downto 1);

  -- TTL-BAR lack of signal counter
  signal ttlbar_nosig_cnt           : t_ttlbar_nosig_cnt;
  signal ttlbar_nosig_n             : std_logic_vector(g_nr_ttl_chan downto 1); 

  -- Temporary signal for blocking and TTL pulse outputs
  signal pulse_outputs              : std_logic_vector(g_nr_ttl_chan downto 1);

  signal blo_ch_en                  : std_logic_vector(g_nr_ttl_chan downto 1); 
  
  -- Temporary signal for inverted-TTL pulse outputs
  signal inv_outputs                : std_logic_vector(g_nr_inv_chan downto 1);
  
  -- Pulse status LED signals
  signal front_led_en               : std_logic_vector(g_nr_ttl_chan downto 1);
  signal rear_led_en                : std_logic_vector(g_nr_ttl_chan downto 1);
  signal pulse_leds                 : std_logic_vector(g_nr_ttl_chan downto 1);
  signal pulse_led_cnt              : t_pulse_led_cnt;

  -- Output enable signals
  signal oe, ttl_oe, blo_oe, inv_oe : std_logic;

  -- Signal for controlling the bicolor LED matrix
  signal bicolor_led_state          : std_logic_vector(23 downto 0);

  signal tmp_pulse : std_logic;
  
  -- Wishbone crossbar signals
  signal xbar_slave_in       : t_wishbone_slave_in_array  (c_nr_masters - 1 downto 0);
  signal xbar_slave_out      : t_wishbone_slave_out_array (c_nr_masters - 1 downto 0);
  signal xbar_master_in      : t_wishbone_master_in_array (c_nr_slaves  - 1 downto 0);
  signal xbar_master_out     : t_wishbone_master_out_array(c_nr_slaves  - 1 downto 0);
  
  -- I2C bridge signals
  signal vbcp_tip            : std_logic;
  signal vbcp_err             : std_logic;
  signal i2c_err_led         : std_logic;
  signal i2c_up              : std_logic;
  signal i2c_addr            : std_logic_vector(6 downto 0);
  signal led_i2c             : std_logic;
  signal led_i2c_clkdiv      : unsigned(22 downto 0);
  signal led_i2c_cnt         : unsigned( 2 downto 0);
  signal blink_state         : std_logic;
  
begin

  --============================================================================
  -- Generate 125 MHz global signal from differential lines
  --============================================================================
  cmp_125_diff_buf : IBUFGDS
  generic map 
  (
    DIFF_TERM    => TRUE,
    IBUF_LOW_PWR => TRUE
  )
  port map 
  (
    I  => fpga_clk_p_i,
    IB => fpga_clk_n_i,
    O  => clk125
  );

  --============================================================================
  -- Internal and external reset generation
  --============================================================================
  -- Configure reset generator for 96ms power-on reset
  cmp_reset_gen : reset_gen
    generic map
    (
      -- Reset time: 12 * 8ns * (10**6) = 96 ms
      g_reset_time => 12*(10**6)
    )
    port map
    (
      clk_i   => clk125,
      rst_i   => '0',
      rst_n_o => rst_n
    );
  
--  rst  <= not rst_n;
  mr_n_o <= rst_n;

  --============================================================================
  -- I2C bridge logic
  --============================================================================
  -- Set the I2C address signal according to ELMA protocol [1]
  i2c_addr <= "10" & fpga_ga_i;
  
  -- Instantiate VBCP bridge component
  cmp_vbcp_bridge : vbcp_wb
    port map
    (
      -- Clock, reset
      clk_i      => clk125,
      rst_n_i    => rst_n,

      -- I2C lines
      sda_en_o   => sda_oe_o,
      sda_i      => sda_i,
      sda_o      => sda_o,
      scl_en_o   => scl_oe_o,
      scl_i      => scl_i,
      scl_o      => scl_o,

      -- I2C address and status
      i2c_addr_i => i2c_addr,

      -- TIP and ERR outputs
      tip_o      => vbcp_tip,
      err_o      => vbcp_err,

      -- Wishbone master signals
      wbm_stb_o  => xbar_slave_in(0).stb,
      wbm_cyc_o  => xbar_slave_in(0).cyc,
      wbm_sel_o  => xbar_slave_in(0).sel,
      wbm_we_o   => xbar_slave_in(0).we,
      wbm_dat_i  => xbar_slave_out(0).dat,
      wbm_dat_o  => xbar_slave_in(0).dat,
      wbm_adr_o  => xbar_slave_in(0).adr,
      wbm_ack_i  => xbar_slave_out(0).ack,
      wbm_rty_i  => xbar_slave_out(0).rty,
      wbm_err_i  => xbar_slave_out(0).err
    );
  
  -- Process to blink the LED for a finite amount of time when the vbcp_tip
  -- signal is set.
  p_i2c_blink : process(clk125)
  begin
    if rising_edge(clk125) then
      if (rst_n = '0') then
        led_i2c_clkdiv <= (others => '0');
        led_i2c_cnt      <= (others => '0');
        led_i2c          <= '0';
        blink_state      <= '0';
      else
        case blink_state is

          when '0' =>
            led_i2c <= '0';
            if (vbcp_tip = '1') then
              blink_state <= '1';
            end if;

          when '1' =>
            led_i2c_clkdiv <= led_i2c_clkdiv + 1;
            if (led_i2c_clkdiv = 2499999) then
              led_i2c_clkdiv <= (others => '0');
              led_i2c_cnt    <= led_i2c_cnt + 1;
              led_i2c        <= not led_i2c;
              if (led_i2c_cnt = 7) then
                led_i2c_cnt <= (others => '0');
                blink_state <= '0';
              end if;
            end if;

          when others =>
            blink_state <= '0';

        end case;
      end if;
    end if;
  end process p_i2c_blink;

  -- Process to set the I2C error LED signal for display on the front panel
  -- of the front module. The I2C error signal is permanently set once an
  -- error is detected from the bridge module.
  p_i2c_err_led : process (clk125) is
  begin
    if rising_edge(clk125) then
      if (rst_n = '0') then
        i2c_err_led <= '0';
      elsif (vbcp_err = '1') then
        i2c_err_led <= '1';
      end if;
    end if;
  end process p_i2c_err_led;

  --============================================================================
  -- Instantiation and connection of the main Wishbone crossbar
  --============================================================================

  cmp_wb_crossbar : xwb_crossbar
  generic map
  (
    g_num_masters => c_nr_masters,
    g_num_slaves  => c_nr_slaves,
    g_registered  => false,
    g_address     => c_addresses,
    g_mask        => c_masks
  )
  port map
  (
    clk_sys_i => clk125,
    rst_n_i   => rst_n,
    slave_i   => xbar_slave_in,
    slave_o   => xbar_slave_out,
    master_i  => xbar_master_in,
    master_o  => xbar_master_out
  );

  --============================================================================
  -- Converter board registers
  --============================================================================
  -- set unused wishbone outputs
  xbar_master_in(c_slv_conv_regs).int <= '0';
  xbar_master_in(c_slv_conv_regs).rty <= '0';
  xbar_master_in(c_slv_conv_regs).err <= '0';

  -- set SWITCH and RTM fields
  switches_n <= ttl_switch_n_i & extra_switch_n_i(7 downto 1);
  rtm_lines  <= rtmp & rtmm;

  -- and instantiate the component
  cmp_conv_regs : conv_regs
    port map (
      rst_n_i                   => rst_n,
      clk_sys_i                 => clk125,
      wb_adr_i                  => xbar_master_out(c_slv_conv_regs).adr(3 downto 2),
      wb_dat_i                  => xbar_master_out(c_slv_conv_regs).dat,
      wb_dat_o                  => xbar_master_in (c_slv_conv_regs).dat,
      wb_cyc_i                  => xbar_master_out(c_slv_conv_regs).cyc,
      wb_sel_i                  => xbar_master_out(c_slv_conv_regs).sel,
      wb_stb_i                  => xbar_master_out(c_slv_conv_regs).stb,
      wb_we_i                   => xbar_master_out(c_slv_conv_regs).we,
      wb_ack_o                  => xbar_master_in (c_slv_conv_regs).ack,
      wb_stall_o                => xbar_master_in (c_slv_conv_regs).stall,

      conv_regs_id_bits_o       => open,
      conv_regs_sr_fwvers_i     => c_fwvers,
      conv_regs_sr_switches_i   => switches_n,
      conv_regs_sr_rtm_i        => rtm_lines,
      conv_regs_cr_rst_unlock_o => open,
      conv_regs_cr_rst_o        => open
    );

  --============================================================================
  -- Output enable logic
  --============================================================================
  -- The general output enable is set first and the blocking, TTL
  -- and INV output enable signals are set one clock cycle later.
  p_oe : process(clk125)
  begin
    if rising_edge(clk125) then
      if (rst_n = '0') then
        oe     <= '0';
        blo_oe <= '0';
        ttl_oe <= '0';
        inv_oe <= '0';
      else
        oe <= '1';
        if (oe = '1') then
          blo_oe <= '1';
          ttl_oe <= '1';
          inv_oe <= '1';
        end if;
      end if;
    end if;
  end process p_oe;

  fpga_oe_o          <= oe;
  fpga_blo_oe_o      <= blo_oe;
  fpga_trig_ttl_oe_o <= ttl_oe;
  fpga_inv_oe_o      <= inv_oe;

  --============================================================================
  -- TTL and blocking pulse generation logic
  --============================================================================
  -- First, the TTL trigger mux, selected via the TTL switch; ttlbar_nosig_n is
  -- controlled in the process below
  trig_ttl_a <= not fpga_input_ttl_n_i when (ttl_switch_n_i = '0') else 
              fpga_input_ttl_n_i and ttlbar_nosig_n;

  -- Then, the blocking trigger
  trig_blo_a <= fpga_blo_in_i;

  -- And now the OR gate at the inputs of the pulse generator blocks
  trig_a     <= trig_ttl_a or trig_blo_a;

  gen_ttl_pulse_generators : for i in 1 to g_nr_ttl_chan generate
    -- First, resync the trigger signal into clk125 domain
    cmp_sync_ffs: gc_sync_ffs
      port map
      (
        clk_i    => clk125,
        rst_n_i  => rst_n,
        data_i   => trig_a(i),
        synced_o => trig_synced(i),
        ppulse_o => trig_synced_edge(i)
      );

    -- Process to detect lack of signal on TTL line
    --
    -- If the signal line is high for 100 us, the ttlbar_nosig_n lines disable
    -- the mux input.
    p_ttlbar_nosig : process(clk125)
    begin
      if rising_edge(clk125) then
        if (rst_n = '0') or (fpga_input_ttl_n_i(i) = '0') then
          ttlbar_nosig_n(i)   <= '1';
          ttlbar_nosig_cnt(i) <= (others => '0');
        elsif (fpga_input_ttl_n_i(i) = '1') then
          ttlbar_nosig_cnt(i) <= ttlbar_nosig_cnt(i) + 1;
          if (ttlbar_nosig_cnt(i) = 12499) then
            ttlbar_nosig_n(i)   <= '0';
            ttlbar_nosig_cnt(i) <= (others => '0');
          end if;
        end if;
      end if;
    end process p_ttlbar_nosig;

    -- Output pulse generators
    cmp_ttl_pulse_gen : ctb_pulse_gen
      generic map
      (
        g_pwidth => 150,
        g_gf_len => 4
      )
      port map
      (
        clk_i     => clk125,
        rst_n_i   => rst_n,
        en_i      => '1',
        gf_en_n_i => extra_switch_n_i(1),
        trig_i    => trig_a(i),
        pulse_o   => pulse_outputs(i)
      );

    -- Pulse outputs assignment
    fpga_out_ttl_o  <= pulse_outputs when (ttl_switch_n_i = '0') else
                       not pulse_outputs;
    fpga_trig_blo_o <= pulse_outputs;
  
    -- Process to flash pulse LED on pulse reception
    p_pulse_led : process (clk125, rst_n) is
    begin
      if rising_edge(clk125) then
        if (rst_n = '0') then
          pulse_led_cnt(i) <= (others => '0');
          pulse_leds(i)    <= '0';
        else
          case pulse_leds(i) is
            when '0' =>
              if (trig_synced_edge(i) = '1') then
                pulse_leds(i) <= '1';
              end if;
            when '1' =>
              pulse_led_cnt(i) <= pulse_led_cnt(i) + 1;
              if (pulse_led_cnt(i) = (pulse_led_cnt(i)'range => '1')) then
                pulse_leds(i) <= '0';
              end if;
            when others =>
              pulse_leds(i) <= '0';
          end case;
        end if;
      end if;
    end process;
  end generate gen_ttl_pulse_generators;
    
  -- Pulse status LED output assignments
  pulse_front_led_n_o <= (not pulse_leds) when (ttl_oe = '1') else 
                         (others => '1');
  pulse_rear_led_n_o  <= (not pulse_leds) when (blo_oe = '1') else 
                         (others => '1');

  --============================================================================
  -- General-purpose INV TTL outputs
  --============================================================================
  inv_out_o <= inv_in_n_i;
  
  --============================================================================
  -- MultiBoot logic
  --============================================================================
  xbar_master_in(c_slv_multiboot).int <= '0';
  xbar_master_in(c_slv_multiboot).rty <= '0';
  xbar_master_in(c_slv_multiboot).err <= '0';

  cmp_multiboot : xil_multiboot
    port map
    (
      clk_i   => clk125,
      rst_n_i => rst_n,

      wbs_i   => xbar_master_out(c_slv_multiboot),
      wbs_o   => xbar_master_in(c_slv_multiboot),

      spi_cs_n_o => fpga_prom_cso_b_n_o,
      spi_sclk_o => fpga_prom_cclk_o,
      spi_mosi_o => fpga_prom_mosi_o,
      spi_miso_i => fpga_prom_miso_i
    );

  --============================================================================
  -- Bicolor LED matrix logic
  --============================================================================
  -- Bicolor LED controls, corresponding to the column orders on the 
  -- bicolor_led_ctrl unit.

  -- WR address
  bicolor_led_state( 1 downto  0) <= c_LED_OFF;

  -- WR GMT
  bicolor_led_state( 3 downto  2) <= c_LED_OFF;

  -- WR link
  bicolor_led_state( 5 downto  4) <= c_LED_OFF;

  -- WR OK
  bicolor_led_state( 7 downto  6) <= c_LED_OFF;

  -- MULTICAST 0
  bicolor_led_state( 9 downto  8) <= c_LED_OFF;

  -- MULTICAST 1
  bicolor_led_state(11 downto 10) <= c_LED_OFF;


  -- I2C
  bicolor_led_state(13 downto 12) <= c_LED_GREEN when (led_i2c = '1') else
                                     c_LED_RED   when (i2c_err_led = '1') else
                                     c_LED_OFF;

  -- State of TTL/TTL_N switch
  bicolor_led_state(15 downto 14) <= c_LED_GREEN when (ttl_switch_n_i = '0') else
                                     c_LED_OFF;

  -- System error
  bicolor_led_state(17 downto 16) <= c_LED_RED when (rtmm_ok = '0') and (rtmp_ok = '0') else
                                     c_LED_OFF;

  -- System power
  bicolor_led_state(19 downto 18) <= c_LED_GREEN;

  -- MULTICAST 2
  bicolor_led_state(21 downto 20) <= c_LED_OFF; 

  -- MULTICAST 3
  bicolor_led_state(23 downto 22) <= c_LED_OFF;

  cmp_bicolor_led_ctrl : bicolor_led_ctrl
    generic map
    (
      g_NB_COLUMN    => 6,
      g_NB_LINE      => 2,
      g_clk_freq     => 125000000,
      g_refresh_rate => 250
    )
    port map
    (
      clk_i           => clk125,
      rst_n_i         => rst_n,
      led_intensity_i => "1111111",
      led_state_i     => bicolor_led_state,
      column_o(0)     => led_wr_ownaddr_i2c_o,
      column_o(1)     => led_wr_gmt_ttl_ttln_o,
      column_o(2)     => led_wr_link_syserror_o,
      column_o(3)     => led_wr_ok_syspw_o,
      column_o(4)     => led_multicast_2_0_o,
      column_o(5)     => led_multicast_3_1_o,
      line_o(0)       => led_ctrl0_o,
      line_o(1)       => led_ctrl1_o,
      line_oen_o(0)   => led_ctrl0_oen_o,
      line_oen_o(1)   => led_ctrl1_oen_o
    );

  --============================================================================
  -- RTM detection logic
  --============================================================================
  rtmm <= not fpga_rtmm_n_i;
  rtmp <= not fpga_rtmp_n_i;

  cmp_rtm_detector : rtm_detector
    port map
    (
      rtmm_i    => rtmm,
      rtmp_i    => rtmp,
      rtmm_ok_o => rtmm_ok,
      rtmp_ok_o => rtmp_ok
    );

end behav;
